blob: b21abc1b2e560b41b885b0f6a478a787f96dd4b6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
# Maintainer: David P. <megver83@parabola.nu>
# Maintainer (Arch): Jan de Groot <jgc@archlinux.org>
pkgname=polkit
pkgver=0.116
pkgrel=3
pkgrel+=.nonsystemd1
pkgdesc="Application development toolkit for controlling system-wide privileges"
arch=(x86_64 i686 armv7h)
license=(LGPL)
url="https://www.freedesktop.org/wiki/Software/polkit/"
depends=(glib2 pam expat elogind js60)
makedepends=(intltool gtk-doc gobject-introspection git autoconf-archive)
provides=(polkit-elogind)
replaces=(polkit-elogind polkit-consolekit)
_commit=941e9329f8d3d43ace8335d206365b212824e686 # tags/0.116
source=("git+https://gitlab.freedesktop.org/polkit/polkit.git#commit=$_commit"
'99-parabola.rules'
'elogind-configure-fix.patch')
sha256sums=('SKIP'
'd28d6ecaf7682860e2b3768bb266bd94313546b7cd0ef3c2eace7b1576c47adb'
'd90b2a95aa3e9e1ebf9369c038c144e04900e095c5405bc4ba4901c31bf3f59b')
pkgver() {
cd $pkgname
git describe --tags | sed 's/-/+/g'
}
prepare() {
cd $pkgname
patch -Np 1 -i ${srcdir}/elogind-configure-fix.patch
NOCONFIGURE=1 ./autogen.sh
}
build() {
cd $pkgname
./configure --prefix=/usr --sysconfdir=/etc \
--localstatedir=/var --libexecdir=/usr/lib \
--enable-libsystemd-login=no --disable-static \
--enable-gtk-doc --with-os-type=redhat \
--enable-libelogind=yes --with-systemdsystemunitdir=no
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
check() {
cd $pkgname
make -k check || :
}
package() {
cd $pkgname
make DESTDIR="$pkgdir" install \
dbusconfdir=/usr/share/dbus-1/system.d \
rulesdir=/usr/share/polkit-1/rules.d
install -d -o root -g 102 -m 750 "$pkgdir"/{etc,usr/share}/polkit-1/rules.d
install -Dm644 /dev/stdin "$pkgdir/usr/lib/sysusers.d/$pkgname.conf" <<END
u polkitd 102 "PolicyKit daemon"
m polkitd proc
END
install -m0644 "${srcdir}"/99-parabola.rules "${pkgdir}"/etc/polkit-1/rules.d
}
# vim: ts=2 sw=2 et:
|
