summaryrefslogtreecommitdiff
path: root/pcr/tahoe-lafs/PKGBUILD
blob: 1d295b1a3c20f06418ee36a8a901170b7aef06b9 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
# Maintainer: Luke R. <g4jc@openmailbox.org> GPG: rsa4096/3EAE8697
# Contributor (Arch) : Skydrome <skydrome@i2pmail.org>
# Contributor (Arch): DaNiMoTh <jjdanimoth@gmail.com>
# Contributor (Arch): Peter Simons <simons@cryp.to>
# Contributor (Arch): Nicolas Pouillard <nicolas.pouillard@gmail.com>

pkgname=tahoe-lafs
pkgver=1.12.1
pkgrel=2
pkgdesc="Secure, decentralized, and fault-tolerant filesystem."
url='https://tahoe-lafs.org/trac/tahoe-lafs'
license=('GPL')
arch=('any')
conflicts=('tahoe-lafs-i2p')
BUILDENV+=(!check)

depends=('openssl>=1.0.2'
         'python2-twisted>=16.1.0'
         'python2-pyopenssl>=0.14'
         'python2-pyasn1>=0.1.8'
         'python2-pyasn1-modules>=0.0.5'
         'python2-zope-interface>=4.0.5'
         'python2-characteristic>=14.3.0'
         'python2-service-identity>=14.0.0'
         'python2-cryptography'
         'pyutil>=1.9.4'
         'python2-simplejson>=3.1.3'
         'nevow>=0.12.0'
         'zbase32>=1.1.5'
         'zfec>=1.4.24'
         'pycryptopp>=0.6.0'
         'python2-cffi'
         'python2-enum34'
         'python2-pycparser'
         'python2-six'
         'libffi'
         'python2-foolscap>=0.12.6'
         'net-tools' # provides /sbin/ifconfig
         'python2-setuptools'
         'python2-shutilwhich>=1.1.0'
         'python2-yaml'
         'python2-crypto>=2.6')

optdepends=('python2-numpy: reliability test')

source=("https://tahoe-lafs.org/downloads/tahoe-lafs-$pkgver.tar.bz2"
        "https://tahoe-lafs.org/downloads/tahoe-lafs-$pkgver.tar.bz2.asc")

sha512sums=('b1017119164d9a7522d8fc0b1405b0634cb6c0386735847d7261e02cb4d08fdb5af13f6feccec73b789efa5bea6f91008f93368514fcb073638aca686086e3ab'
            'e23f83106b77bded93d23d1237b0419dddf558f1db266ff54038ebf52606a4a94df6ec711d0ef749f458a248fbd36e3ec6025e798059825e9ee071dbaa2aa81b')

validpgpkeys=('E34E62D06D0E69CFCA4179FFBDE0D31D68666A7A') # Tahoe-LAFS Release-Signing Key

build(){
    cd "${srcdir}/tahoe-lafs-${pkgver}"
    python2 setup.py build
}

check() {
    cd "${srcdir}/tahoe-lafs-${pkgver}"
    msg "This may take a while"
    python2 bin/tahoe debug trial $MAKEFLAGS
}

package(){
    cd "${srcdir}/tahoe-lafs-${pkgver}"
    python2 setup.py install --root="$pkgdir" --optimize=1
    install -Dm644 COPYING.GPL "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
}