summaryrefslogtreecommitdiff
path: root/~lukeshu/conkeror-git/PKGBUILD
blob: 5d68e26c939b6e7c21cba9d6c0dee9c1e68f1806 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
# Maintainer (parabola): Luke Shumaker <lukeshu@sbcglobal.net
# Maintainer (aur): Ivy Foster <joyfulgirl@archlinux.us>
# Maintainer (k[community]): Stefan Husmann <stefan-husmann@t-online.de>
# Contributor: Heeru Kiyura <M8R-p9i5nh@mailinator.com>

_pkgname=conkeror
pkgname=conkeror-git
pkgver=20120228
pkgrel=1
pkgdesc="A highly programmable web browser based on Mozilla XULRunner."
arch=('any')
url="http://conkeror.mozdev.org/"
license=('MPL' 'GPL' 'LGPL')
depends=('xulrunner' 'desktop-file-utils')
makedepends=('imagemagick')
provides=(conkeror)
source=(
  https://repo.parabolagnulinux.org/sources/~lukeshu/$pkgname-$pkgver-1-any.src.tar.xz
  conkeror_gimpfile.xpm conkeror.sh)
changelog=ChangeLog
install=conkeror-git.install

build() {
  cd "$srcdir/$_pkgname"
  make
}

package() { 
  cd "$srcdir/$_pkgname"

  install -d "$pkgdir"/usr/share/{conkeror,man/man1,pixmaps}
  cp -a "$srcdir/$_pkgname"/* "$pkgdir"/usr/share/conkeror

  install -Dm644 "$pkgdir"/usr/share/conkeror/contrib/man/conkeror.1 \
    "$pkgdir"/usr/share/man/man1/conkeror.1
  install -Dm644 "$srcdir/$_pkgname"/debian/conkeror.desktop \
    "$pkgdir"/usr/share/applications/conkeror.desktop
  install -Dm644 "$srcdir"/conkeror_gimpfile.xpm "$pkgdir"/usr/share/pixmaps

  install -Dm755 "$srcdir"/conkeror.sh "$pkgdir"/usr/bin/conkeror

  mv "$pkgdir"/usr/share/conkeror/conkeror-spawn-helper "$pkgdir"/usr/bin
  rm "$pkgdir"/usr/share/conkeror/conkeror-spawn-helper.c
  rm -r "$pkgdir"/usr/share/conkeror/contrib/man
  rm -r "$pkgdir"/usr/share/conkeror/debian
} 

md5sums=('5ebcc14496e6b232f61b42dcbc609d61'
         'b592582a5b923db1707615564a95737f'
         '11c6c76a2639254754b34a542f1965a1')