summaryrefslogtreecommitdiff
path: root/~lukeshu/redo/PKGBUILD
blob: fa9bdefc22e51b8475dbd06080b69d45fb0c364d (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
# Maintainer: Luke Shumaker <lukeshu@sbcglobal.net>

pkgname=redo
pkgver=0.06
pkgrel=1
pkgdesc="A competitor to make based on essays by DJB."
arch=('any')
url="https://github.com/apenwarr/$pkgname"
license=('GPL2')
depends=('python2')
source=("$pkgname-$pkgver.tar.gz::https://github.com/apenwarr/$pkgname/tarball/$pkgname-$pkgver")

build() {
  cd "$srcdir/apenwarr-$pkgname-"*

  # Make everything use python2
  sed -i 's@^#!/usr/bin/python$@#!/usr/bin/python2@' *.py
  sed -i 's@/usr/bin/env python@/usr/bin/env python2@' Documentation/md2man.py
  sed -i -e 's@^python @python2 @' \
         -e 's@/usr/bin/python$@/usr/bin/python2@' \
         install.do

  make
}

check() {
  cd "$srcdir/apenwarr-$pkgname-"*
  make test
}

package() {
  cd "$srcdir/apenwarr-$pkgname-"*
  make install DESTDIR="$pkgdir"
}

md5sums=('0faa0e98f3d60fdcdea826dad59923c8')