#!/usr/bin/sed -rf
# librefetchdir/makepkg.gen
#
# Copyright (C) 2013-2017 Luke Shumaker <lukeshu@sbcglobal.net>
#
# License: GNU GPLv3+
#
# This file is part of LibreFetch.
#
# LibreFetch is free software: you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation, either version 3 of the License, or
# (at your option) any later version.
#
# LibreFetch is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with LibreFetch. If not, see <http://www.gnu.org/licenses/>.

/LIBRARY=/iexport LIBRARY="${0%/*}/libmakepkg"

/create_package\(\) \{/,/^\}$/ {
	/pkg_file=/d                  # allow us to set pkg_file
	s/"?\$\{comp_files\[@\]\}"?// # do not include .{PKGINFO,BUILDINGO,CHANGELOG,INSTALL,MTREE}
	# This is long/gross.  What it does:
	#  - pass --format=ustar to bsdtar, to inhibit it using the pax format
	#  - take the files that would be included in the tarball, and use
	#    find/sort/--files-from to order them for bsdtar
	s/bsdtar(.*) - ([^|]*) \|/find \2 -print0 | LC_ALL=C sort --zero-terminated | bsdtar --null --files-from - --format=ustar --no-recursion \1 - |/
	s/create_signature .*/&; return/ # do not procede to create symlinks
}

s|Making package:|Making source:|
s|Checking runtime dependencies\.\.\.|Checking source dependencies...|
 /Checking buildtime dependencies\.\.\./d

s|srcdir=.*|&-libre|
s|pkgdirbase=.*|&-libre|
s|check_build_status$|:|