# $Id: PKGBUILD 198320 2013-10-30 14:09:04Z allan $
# Maintainer: Tobias Powalowski <tpowa@archlinux.org>

pkgname=misdnuser
pkgver=2.0.17_20120917
pkgrel=3
pkgdesc="Tools and library for mISDN"
arch=('i686' 'x86_64')
url="http://www.misdn.org"
license=('GPL')
depends=('isdn4k-utils' 'spandsp')
backup=('etc/capi20.conf') 
options=('!makeflags' '!strip')
source=(ftp://ftp.archlinux.org/other/misdnuser/${pkgname}-${pkgver}.tar.gz
        mISDNcapid.service
        c2faxrecv-mISDNcapid.service
        mISDNcapid.conf
        fix-compile-gcc48.patch)

prepare() {
  cd ${srcdir}/${pkgname}-${pkgver}
  # fix gcc48 compile error
  patch -Np1 -i ${srcdir}/fix-compile-gcc48.patch
}

build() {
  # only enable for debugging!
  #export CFLAGS+=" -g -O0"
  #export CXXFLAGS+=" -g -O0"
  cd ${srcdir}/${pkgname}-${pkgver}
  make
  ./configure --prefix=/usr --sbindir=/usr/bin --sysconfdir=/etc --enable-capi --enable-softdsp --with-mISDN_group=uucp
  make
}

package() {
  cd ${srcdir}/${pkgname}-${pkgver}
  make DESTDIR=${pkgdir} install
  # fix udev rule
  mkdir -p ${pkgdir}/usr/lib/udev/rules.d
  mv ${pkgdir}/etc/udev/rules.d/45-misdn.rules ${pkgdir}/usr/lib/udev/rules.d
  rm -r ${pkgdir}/etc/udev/
  # add systemd files
  install -D -m644 ${srcdir}/mISDNcapid.service ${pkgdir}/usr/lib/systemd/system/mISDNcapid.service
  # mISDNcapid:
  # tends to crash on avmfritz card, add an extra systemd file for
  # restarting the services until segfaults are fixed!
  install -D -m644 ${srcdir}/c2faxrecv-mISDNcapid.service ${pkgdir}/usr/lib/systemd/system/c2faxrecv-mISDNcapid.service
  install -D -m644 ${srcdir}/mISDNcapid.conf ${pkgdir}/usr/lib/tmpfiles.d/mISDNcapid.conf
}
md5sums=('4cdb52f2c0ff1a1426573ac5ef09e9f8'
         'bfd47480a54b41394ba5cc3f53587130'
         '32ead7f063e007c784aa883d441f33c2'
         '42c3b46880a68c3883ee1ed00af34b45'
         'b291e9a04378decec33c420a62a5a4b7')