# $Id: PKGBUILD 198404 2013-10-30 14:39:57Z allan $
# Maintainer: Gaetan Bisson <bisson@archlinux.org>
# Contributor: damir <damir@archlinux.org>
# Contributor: Gan Lu <rhythm.gan@gmail.com>

pkgname=scim
pkgver=1.4.14
pkgrel=5
pkgdesc='Input method user interface and development platform'
url='http://www.scim-im.org/projects/scim'
license=('LGPL')
arch=('i686' 'x86_64')
depends=('libltdl' 'gtk2')
optdepends=('qt4: qt4 immodule'
            'gtk3: gtk3 immodule')
makedepends=('intltool' 'qt4' 'gtk3' 'optipng')
source=("http://downloads.sourceforge.net/project/${pkgname}/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.gz")
sha1sums=('73391be371dd7ef9f9af8b3a211e2bedec0cf71b')

backup=('etc/scim/config' 'etc/scim/global')
install=install

build() {
	cd "${srcdir}/${pkgname}-${pkgver}"
	find -name '*.png' -exec optipng -quiet -force -fix {} +
	./configure \
		--prefix=/usr \
		--sysconfdir=/etc \
		--disable-static \
		--with-qt4-moc=/usr/bin/moc-qt4 \
		--with-gtk-version=2 # no gtk3 support in scim-anthy

	make
}

package() {
	cd "${srcdir}/${pkgname}-${pkgver}"
	make DESTDIR="${pkgdir}" install
}