blob: f26e5da1cf3dbe65dc7dd5fd3583b2562097754e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# $Id: PKGBUILD 116015 2014-07-20 04:16:39Z xyne $
# Maintainer: Xyne <ca dot archlinux at xyne, backwards>
# Contributor: Bartłomiej Piotrowski <nospam@bpiotrowski.pl>
# Contributor: Aaron Griffin <aaron@archlinux.org>
# Contributor: dorphell <dorphell@archlinux.org>
pkgname=cmus
pkgver=2.5.1
pkgrel=2
pkgdesc='Very feature-rich ncurses-based music player'
arch=('i686' 'x86_64')
url="https://cmus.github.io/"
license=('GPL')
depends=('ncurses' 'libcue')
makedepends=(
'faad2'
'ffmpeg'
'flac'
'libao'
'libcdio-paranoia'
'libmad'
'libmodplug'
'libmp4v2'
'libmpcdec'
'libpulse'
'libvorbis'
'opusfile'
'wavpack'
)
optdepends=('alsa-lib: for ALSA output plugin support'
'libao: for AO output plugin support'
'libpulse: for PulseAudio output plugin support'
'faad2: for AAC input plugin support'
'ffmpeg: for ffmpeg input plugin support'
'flac: for flac input plugin support'
'libmad: for mp3 input plugin support'
'libmodplug: for modplug input plugin support'
'libmp4v2: for mp4 input plugin support'
'libmpcdec: for musepack input plugin support'
'libvorbis: for vorbis input plugin support'
'libcdio-paranoia: for cdio support'
'opusfile: for opus input plugin support'
'wavpack: for wavpack input plugin support')
source=("https://github.com/cmus/cmus/archive/v${pkgver}.tar.gz")
sha256sums=('2c22b12eb2e2d038b64e8db804d4dc037ac68cbd3a398b3e405c2d0ce5c15229')
build() {
cd "$srcdir/$pkgname-$pkgver"
./configure prefix=/usr
make
}
package() {
cd "$srcdir/$pkgname-$pkgver"
make DESTDIR="$pkgdir" install
install -Dm644 contrib/_cmus "$pkgdir"/usr/share/zsh/site-functions/_cmus
}
|
