summaryrefslogtreecommitdiff
path: root/community/kdenlive/PKGBUILD
blob: 747528c6fe7395a7badaaff468e8659be1986fce (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
# $Id: PKGBUILD 111179 2014-05-15 14:14:12Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Zuf <kontakt.zuf@gmail.com>
# Contributor: Darwin Bautista <djclue917@gmail.com>

pkgname=kdenlive
pkgver=0.9.8
pkgrel=1
pkgdesc="A non-linear video editor for Linux"
arch=('i686' 'x86_64')
# http://download.kde.org/stable/kdenlive/
url="http://www.kdenlive.org/"
license=('GPL')
depends=('kdebase-runtime' 'mlt' 'qjson' 'libqzeitgeist')
makedepends=('automoc4' 'cmake' 'gettext' 'mesa' 'glu')
optdepends=('recordmydesktop: screen capture'
	    'dvdauthor: dvd creation'
	    'dvgrab: firewire capture'
	    'xine-ui: dvd preview'
	    'cdrkit: dvd iso image creation')
install=kdenlive.install
options=('docs')
source=(http://download.kde.org/stable/kdenlive/$pkgver/src/kdenlive-$pkgver.tar.bz2)
md5sums=('589801ff79c5819936141abe7e4f44fc')

build() {
  export LDFLAGS="$LDFLAGS -lX11"
  cd "${srcdir}"
  mkdir -p build
  cd build
  cmake ../kdenlive-${pkgver} \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DLIB_INSTALL_DIR=/usr/lib \
    -DLINK_LIBRARIES=-lX11 \
    -DWITH_Nepomuk=OFF
  make
}

package() {
  cd "${srcdir}"/build
  make DESTDIR="${pkgdir}" install
}