summaryrefslogtreecommitdiff
path: root/extra/ebtables/PKGBUILD
blob: ce47a9081567c611a4980a1d1fa2b701893b9e67 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
# $Id: PKGBUILD 217757 2014-07-23 22:33:19Z seblu $
# Maintainer: Sébastien Luttringer
# Contributor: Michal Soltys <soltys@ziu.info>

pkgname=ebtables
pkgver=2.0.10_4
pkgrel=4
pkgdesc='Ethernet bridge filtering utilities'
arch=('i686' 'x86_64')
url='http://ebtables.sourceforge.net/'
depends=('perl' 'bash')
license=('GPL2')
backup=("etc/$pkgname.conf")
# ebtables segfault with --as-needed
options=('!buildflags')
install=$pkgname.install
source=("http://downloads.sourceforge.net/${pkgname}/${pkgname}-v${pkgver/_/-}.tar.gz"
        "$pkgname.systemd"
        "$pkgname.service")
md5sums=('506742a3d44b9925955425a659c1a8d0'
         'b4c329060809e5b290ae49fbd0ad61f2'
         'baf923443c3b16277e50d60d2e68f534')

build() {
  cd $pkgname-v${pkgver/_/-}
  make CFLAGS='-Wunused -Wall -Werror -Wno-error=unused-but-set-variable'
}

package() {
  pushd $pkgname-v${pkgver/_/-}
  make install \
    DESTDIR="$pkgdir" \
    LIBDIR=/usr/lib \
    MANDIR=/usr/share/man \
    BINDIR=/usr/bin \
    INITDIR=/etc/rc.d \
    SYSCONFIGDIR=/etc
  popd
  # rm package ebtables rc.d scripts
  rm "$pkgdir/etc/ebtables-config"
  rm -r "$pkgdir/etc/rc.d"
  # systemd
  install -Dm 755 $pkgname.systemd \
    "$pkgdir/usr/lib/systemd/scripts/$pkgname"
  install -Dm 644 $pkgname.service \
    "$pkgdir/usr/lib/systemd/system/$pkgname.service"
  # default config file
  install -Dm 644 /dev/null "$pkgdir/etc/$pkgname.conf"
}

# vim:set ts=2 sw=2 et: