jdee-svn-300-1: updating version

1 files changed, 40 insertions, 0 deletions

diff --git a/pcr/jdee-svn/PKGBUILD b/pcr/jdee-svn/PKGBUILD
new file mode 100644
index 000000000..cadfc9bab
--- /dev/null
+++ b/pcr/jdee-svn/PKGBUILD
@@ -0,0 +1,40 @@
+# Contributor (Arch): Brandon Ednes <brandon@as220.org>
+# Contributor (Arch): Stefan Husmann <stefan-husmann@t-online.de>
+# Maintainer : Omar Vega Ramos <ovruni@gnu.org.pe>
+
+pkgname=jdee-svn
+pkgver=300
+_pkgver=2.4.2
+pkgrel=1
+pkgdesc="Java Development Environment for Emacs"
+arch=('any')
+url="http://jdee.sourceforge.net/"
+license=('GPL')
+depends=('emacs-elib' 'java-environment')
+makedepends=('subversion' 'apache-ant-contrib=1.0b3')
+provides=('jdee')
+conflicts=('jdee')
+source=("svn+https://jdee.svn.sourceforge.net/svnroot/jdee/trunk/jdee")
+md5sums=('SKIP')
+_svnmod="jdee"
+
+pkgver() {
+  cd "$srcdir/${_svnmod}"
+  local ver="$(svnversion)"
+  printf "%s" "${ver//[[:alpha:]]}"
+}
+
+build() {
+  cd $srcdir/${_svnmod}
+  export CLASSPATH=$CLASSPATH:/usr/share/java/apache-ant/ant-contrib-1.0b3.jar
+  ant clean-all
+  ant configure
+  ant bindist
+}
+
+package() {
+  cd $srcdir/${_svnmod}/dist/jdee-${_pkgver}
+  install -d $pkgdir/usr/share/java/jdee/{lisp,java/lib}
+  cp -r java/lib/ $pkgdir/usr/share/java/jdee/java/
+  cp -r lisp/ $pkgdir/usr/share/java/jdee/
+}