PCR: Add open-plc-utils

This package was updated from AUR

Signed-off-by: Denis 'GNUtoo' Carikli <GNUtoo@cyberdimension.org>

1 files changed, 37 insertions, 0 deletions

diff --git a/pcr/open-plc-utils/PKGBUILD b/pcr/open-plc-utils/PKGBUILD
new file mode 100644
index 000000000..50859ada3
--- /dev/null
+++ b/pcr/open-plc-utils/PKGBUILD
@@ -0,0 +1,37 @@
+# Maintainer: (AUR) Mantas Mikulėnas <grawity@gmail.com>
+# Contributor: Denis 'GNUtoo' Carikli <GNUtoo@cyberdimension.org>
+pkgname=open-plc-utils
+# open-plc-utils has releases but currently it doesn't seem
+# to have any clear versioning scheme definition. Because
+# of that pkgver calculed dynamically, from the number of
+# commits. However, if the pkgver variable is not defined
+# as such, makepkg will complain about it:
+# ==> ERROR: pkgver is not allowed to be empty.
+# This is why we have to define a bogus variable here.
+pkgver=r229.g18a17597
+pkgrel=1
+pkgdesc="Qualcomm Atheros Open Powerline Toolkit for HomePlug AV"
+arch=(armv7h i686 x86_64)
+url=https://github.com/qca/open-plc-utils
+license=(custom:Clear_BSD)
+_tag=OSRQCA-929
+source=("git+https://github.com/qca/open-plc-utils#tag=$_tag")
+sha256sums=('SKIP')
+
+pkgver() {
+	cd $pkgname
+	echo r$(git rev-list --count HEAD).g$(git rev-parse --short HEAD)
+}
+
+build() {
+	cd $pkgname
+	make
+}
+
+package() {
+	cd $pkgname
+	make ROOTFS="$pkgdir" BIN="$pkgdir"/usr/bin install manuals
+	mv "$pkgdir"/usr/bin/amptest{,.plc}
+	mv "$pkgdir"/usr/bin/pev{,.plc}
+	install -D -m 644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}