pcr: Add xtrx version of soapyosmo

Signed-off-by: Denis 'GNUtoo' Carikli <GNUtoo@cyberdimension.org>

1 files changed, 47 insertions, 0 deletions

diff --git a/pcr/soapyosmo-xtrx/PKGBUILD b/pcr/soapyosmo-xtrx/PKGBUILD
new file mode 100644
index 000000000..ac5906a22
--- /dev/null
+++ b/pcr/soapyosmo-xtrx/PKGBUILD
@@ -0,0 +1,47 @@
+# Maintainer (ARCH): Filipe Laíns (FFY00) <lains@archlinux.org>
+# Contributor: Denis 'GNUtoo' Carikli <GNUtoo@cyberdimension.org>
+
+pkgname=soapyosmo-xtrx
+_pkgname=SoapyOsmo
+pkgver=0.2.5
+_gitver=soapy-osmo-$pkgver
+pkgrel=2
+pkgdesc='SoapySDR plugins for OsmoSDR devices'
+arch=('x86_64')
+url='https://github.com/pothosware/SoapyOsmo'
+license=('GPL3')
+depends=('soapysdr' 'gnuradio-osmosdr-xtrx' 'boost-libs')
+makedepends=('cmake' 'boost' 'airspy' 'hackrf' 'libosmosdr' 'rtl-sdr') # 'bladerf'
+optdepends=('airspy: AirSpy support'
+            'hackrf: HackRF support'
+            'libosmosdr: OsmoSDR support'
+            'rtl-sdr: RTL-SDR support')
+#            'bladerf: BladeRF support'
+source=("$pkgname-$pkgver.tar.gz::$url/archive/$_gitver.tar.gz")
+sha512sums=('a1aa5f3c84f5e9cf8cc0329445836162586c3fd301f126310e2a3131c170f1d213fcb214162a28c448a49f57fcf177b7a00d10967ba88a8434a6ac26fa2264e8')
+
+prepare() {
+  sed -i 's|#ADD_DEFINITIONS(-Wconversion)|SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -pthread")|' $_pkgname-$_gitver/CMakeLists.txt
+}
+
+build() {
+  mkdir -p $_pkgname-$_gitver/build
+  cd $_pkgname-$_gitver/build
+
+  cmake .. \
+  	-DCMAKE_INSTALL_PREFIX=/usr \
+  	-DCMAKE_BUILD_TYPE=Release \
+  	-DUSE_OSMO_RTLSDR=ON \
+  	-DUSE_OSMO_HACKRF=ON \
+  	-DUSE_OSMO_AIRSPY=ON
+
+#  	-DUSE_OSMO_BLADERF=ON \
+
+  make
+}
+
+package() {
+  cd $_pkgname-$_gitver/build
+
+  make DESTDIR="$pkgdir" install
+}