pcr/xpra: add new package to [pcr]

1 files changed, 36 insertions, 0 deletions

diff --git a/pcr/xpra/PKGBUILD b/pcr/xpra/PKGBUILD
new file mode 100644
index 000000000..f2a3d3966
--- /dev/null
+++ b/pcr/xpra/PKGBUILD
@@ -0,0 +1,36 @@
+# Maintainer: Márcio Silva <coadde@parabola.nu>
+
+pkgname=xpra
+pkgver=0.17.1
+pkgrel=1
+pkgdesc='multi-platform X11 screen and application forwarding system'
+arch=('i686' 'x86_64' 'armv7h')
+license=('GPL2')
+url="https://www.$pkgname.org"
+backup=("etc/$pkgname/"{xorg,$pkgname}".conf")
+depends=('gtk3' 'ffmpeg' 'python-cairo' 'xorg-server') # 'xvidcore': needs similar to support xvid
+optdepends=('cups: CUPS (printing) support'
+            'python-lcms: LittleCMS support'
+            'python-lz4: LZ4 compression support'
+            'python-lzo: LZO compression support'
+            'python-pycups: CUPS (printing) support'
+            'python-pyopencl: OpenCL support'
+            'xf86-video-dummy: Xdummy support')
+makedepends=('cups' 'cython' 'lsb-release' 'python2-cairo' 'xf86-video-dummy')
+source=("$url/src/$pkgname-$pkgver.tar.xz")
+sha1sums=('9303e0ca5d60e5f9d5497b1012ce7829dc642dec')
+
+build () {
+  cd $pkgname-$pkgver
+  CFLAGS="$CFLAGS -fno-strict-aliasing" python setup.py build \
+    --with-{csc_opencl,gtk_x11,server,shadow,verbose,Xdummy{,_wrapper}} --without-{csc_libyuv,xvid}
+  cd rencode
+  python setup.py build
+}
+
+package() {
+  cd $pkgname-$pkgver
+  python setup.py install --root=$pkgdir
+  cd rencode
+  python setup.py install --root=$pkgdir
+}