blob: d7090cc0dc01b6efcf83929cd054c730bbb6e8fe (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
|
# Maintainer: Luke Shumaker <lukeshu@sbcglobal.net>
# Maintainer (AUR): David Campbell <davekong@archlinux.us>
_gemname=mustache
pkgname=ruby-$_gemname
pkgver=0.99.4
pkgdesc="A framework-agnostic way to render logic-free views."
url="http://mustache.github.io/"
license=('custom:MIT')
pkgrel=3
arch=('any')
depends=('ruby>=2')
makedepends=('rubygems')
source=("http://gems.rubyforge.org/gems/mustache-${pkgver}.gem")
md5sums=('650194ec2c166feb087377647414b9dc')
noextract=($_gemname-$pkgver.gem)
package() {
cd "${srcdir}"
local _gemdir="$(ruby -rubygems -e'puts Gem.default_dir')"
gem install --no-user-install --ignore-dependencies -i "$pkgdir$_gemdir" -n "$pkgdir/usr/bin" \
"$_gemname-$pkgver.gem"
install -Dm644 "$pkgdir$_gemdir"/gems/$_gemname-$pkgver/LICENSE \
"$pkgdir"/usr/share/licenses/$pkgname/LICENSE
shopt -s nullglob
for file in "$pkgdir$_gemdir"/gems/$_gemname-$pkgver/man/*.{1..8}; do
install -Dm644 "$file" "$pkgdir"/usr/share/man/man${file##*.}/${file##*/}
done
}
|
