libre/abiword-libre/PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98

# $Id: PKGBUILD 183900 2013-04-29 15:40:28Z bpiotrowski $
# Maintainer: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: Maël Lavault <moimael@neuf.fr>
# Maintainer (Parabola): André Silva <emulatorman@lavabit.com>

_pkgbase=abiword
pkgbase=abiword-libre
pkgname=('abiword-libre' 'abiword-libre-plugins')
pkgver=2.8.6
pkgrel=9.1
arch=('i686' 'x86_64' 'mips64el')
license=('GPL')
url="http://www.abisource.com"
makedepends=('pkgconfig' 'asio' 'boost' 'fribidi' 'goffice0.8' 'libwmf' 'wv' 'link-grammar' 'gtkmathview' 
             'aiksaurus' 'libxslt' 'enchant' 'libots' 'libwpg' 'librsvg' 'loudmouth' 'libsoup' 'psiconv' 'ttf-liberation')
options=('!makeflags' '!libtool')
source=(http://www.abisource.com/downloads/${_pkgbase}/${pkgver}/source/${_pkgbase}-${pkgver}.tar.gz
        compat_libwpg_0_9.patch
	abiword-2.8.6-no-undefined.patch
        abiword-2.8.6-libpng15.patch
        abiword-2.8.6-glib-2.31.patch
        liberation-fonts.patch)
md5sums=('f883b0a7f26229a9c66fd6a1a94381aa'
         '09446a2ebba8288fc611e88f7cf17298'
         '42e2614b6e0aad457d91f6ce20b6f225'
         '40e370e7e88c5437140ef18037abfbd3'
         '6ec338a27a6fb590c348724ddb545849'
         '880b17db6f249d977d2a7cd012d9ce02')

build() {
  cd "${srcdir}/${_pkgbase}-${pkgver}"

  patch -Np1 -i "${srcdir}/compat_libwpg_0_9.patch"
  # fix a gcc 4.6.x build issue, patch from Fedora
  patch -Np1 -i "${srcdir}/abiword-2.8.6-no-undefined.patch"
  patch -Np0 -i "${srcdir}/abiword-2.8.6-libpng15.patch"

  # Fix build with recent glib, patch from Gentoo
  patch -Np0 -i "${srcdir}/abiword-2.8.6-glib-2.31.patch"

  # Replace non-free fonts support to liberation fonts
  patch -Np1 -i "${srcdir}/liberation-fonts.patch"

  libtoolize --force
  autoreconf

  ./configure --prefix=/usr \
              --enable-clipart \
              --enable-templates \
              --enable-collab-backend-xmpp \
              --enable-collab-backend-tcp \
              --enable-collab-backend-service \
              --disable-collab-backend-sugar \
              --enable-plugins --without-gnomevfs \
              --with-gio \
              --with-goffice \
              --disable-static \
              --with-psiconv-config=/nothere
  make
}

package_abiword-libre() {
  pkgdesc="A fully-featured word processor that doesn't recommend nonfree fonts"
  depends=('fribidi' 'wv' 'goffice0.8' 'librsvg' 'enchant' 'desktop-file-utils')
  install=$pkgname.install
  optdepends=('abiword-libre-plugins')
  conflicts=("abiword-libre-plugins<${pkgver}-${pkgrel}" 'abiword')
  replaces=('abiword')
  provides=("abiword=$pkgver")

  cd "${srcdir}/${_pkgbase}-${pkgver}"
  sed -i plugins/Makefile \
      -e 's/ collab / /' \
      -e 's/ wpg / /' \
      -e 's/ wmf / /' \
      -e 's/ grammar / /' \
      -e 's/ mathview / /' \
      -e 's/ aiksaurus / /' \
      -e 's/ latex / /' \
      -e 's/ ots / /' \
      -e 's/ wordperfect / /'
  make DESTDIR="${pkgdir}" install
}

package_abiword-libre-plugins() {
  pkgdesc="Additional plugins for Abiword"
  depends=("abiword-libre=${pkgver}-${pkgrel}" 'loudmouth' 'libwpg' 'libwmf' 'link-grammar' 
           'gtkmathview' 'aiksaurus' 'libxslt' 'libsoup' 'libots' 'libgsf')
  conflicts=('abiword-plugins')
  replaces=('abiword-plugins')
  provides=("abiword-plugins=$pkgver")
  
  cd "${srcdir}/${_pkgbase}-${pkgver}/plugins"
  
  for dir in collab wpg wmf grammar mathview aiksaurus latex ots wordperfect; do
    make -C ${dir} DESTDIR="${pkgdir}" install
  done
}