blob: 252dd20be91ef62f14339dd8de262658afb4b792 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
|
# Maintainer (Arch): Sven-Hendrik Haase <sh@lutzhaase.com>
# Contributor (Arch): John Sowiak <john@archlinux.org>
# Contributor (Arch): tobias <tobias@archlinux.org>
# Contributor: Andreas Grapentin <andreas@grapentin.org>
# Contributor: Márcio Silva <coadde@hyperbola.info>
# Contributor: bill-auger <bill-auger@programmer.net>
# parabola changes and rationale:
# - removed support for non-free CUDA and optix
# - set OS type string to GNU/Linux-libre
# - pin to tightly-coupled dependency versions
pkgname=blender
pkgver=2.91.0
pkgrel=4
pkgrel+=.parabola1
epoch=17
_pythonver_x86_64=3.9
_pythonvver_i686=3.8
_pythonvver_armv7h=3.9
eval "_python_ver=\$_pythonvver_${CARCH}"
pkgdesc="A fully integrated 3D graphics creation suite"
pkgdesc+=", without non-free CUDA or optix support"
arch=('x86_64')
arch+=('i686' 'armv7h')
license=('GPL')
url="http://www.blender.org"
depends=('libpng' 'libtiff' 'openexr' 'python' 'desktop-file-utils' 'python-requests' 'potrace'
'shared-mime-info' 'hicolor-icon-theme' 'xdg-utils' 'glew' 'openjpeg2' 'python-numpy'
'freetype2' 'openal' 'ffmpeg' 'fftw' 'boost-libs' 'opencollada' 'alembic' 'openxr'
'openimageio' 'libsndfile' 'jack' 'opencolorio' 'openshadinglanguage'
'jemalloc' 'libspnav' 'ptex' 'opensubdiv' 'openvdb' 'log4cplus' 'sdl2')
depends_x86_64=('embree' 'openimagedenoise')
depends_i686=('embree')
[[ "${CARCH}" == 'i686' ]] && depends[21]='openimageio=2.1.16.0' # FIXME: special case dep - presently, 'openxr' is only in community-testing;
# but 'community-testing/openimageio' is incompatible with 'openshadinglanguage'
makedepends=('cmake' 'boost' 'mesa' 'git' 'llvm' 'ninja')
options=(!strip)
source=("git://git.blender.org/blender.git#tag=v$pkgver"
"git://git.blender.org/blender-addons.git"
"git://git.blender.org/blender-addons-contrib.git"
"git://git.blender.org/blender-translations.git"
"git://git.blender.org/blender-dev-tools.git")
sha512sums=('SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP')
_version_constraint() # (dep_pkgname [precision])
{
local dep_pkgname=$1
local full_version=$(pacman -S --print-format='%v' ${dep_pkgname} | tail -n 1)
local n_dots=$(tmp=${full_version%-*} ; tmp=${tmp//[^\.]} ; echo "${#tmp}" ;)
local def_precision=$(( n_dots + 1 ))
local precision=$( [[ "$2" =~ ^[1-${def_precision}]$ ]] && echo $2 || echo ${def_precision} )
local pkgver_rx='[^-\.\ ]+'
local subver_rx='\.'${pkgver_rx}
local pkgrel_rx='[^-\ ]+'
local capture_rx=${pkgver_rx}
for (( n_dots=1 ; n_dots < precision ; n_dots++ )) ; do capture_rx+=${subver_rx} ; done ;
if [[ "${full_version}" =~ ^(${capture_rx})(${subver_rx})*-${pkgrel_rx}$ ]]
then local version=${BASH_REMATCH[1]}
local subver_inc=$(( ${version##*.} + 1 ))
local version_inc=$( [[ "${version}" =~ \. ]] && echo ${version%.*}.${subver_inc} || \
echo ${subver_inc} )
local constraint_string="${dep_pkgname}>=${version} ${dep_pkgname}<${version_inc}"
echo "applied version constraint: ${constraint_string}" >&2
echo -n "${constraint_string}"
else echo "ERROR: _version_constraint() error parsing: dep_pkgname='${dep_pkgname}' full_version='${full_version}'" >&2
exit 1
fi
}
prepare() {
cd "$pkgname"
git submodule init
git config submodule."release/scripts/addons".url "${srcdir}/blender-addons"
git config submodule."release/scripts/addons_contrib".url "${srcdir}/blender-addons-contrib"
git config submodule."release/datafiles/locale".url "${srcdir}/blender-translations"
git config submodule."source/tools".url "${srcdir}/blender-dev-tools"
git submodule update
git submodule foreach git checkout v${pkgver}
# set OS type string
sed -i 's|BUILD_PLATFORM;|"GNU/Linux-libre";|' 'source/creator/buildinfo.c'
}
build() {
cd "$pkgname"
cmake . \
-Bbuild \
-GNinja \
-Cbuild_files/cmake/config/blender_release.cmake \
-DWITH_CYCLES_DEVICE_OPTIX=OFF \
-DWITH_CYCLES_CUDA_BINARIES='OFF' \
-DWITH_CYCLES_DEVICE_CUDA='OFF' \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_BUILD_TYPE=Release \
-DWITH_INSTALL_PORTABLE=OFF \
-DWITH_PYTHON_INSTALL=OFF \
-DPYTHON_VERSION=${_python_ver} \
-DPYTHON_LIBPATH=/usr/lib \
-DPYTHON_LIBRARY=python${_python_ver} \
-DPYTHON_INCLUDE_DIRS=/usr/include/python${_python_ver} \
-DCMAKE_CXX_FLAGS="-I /usr/include/python${_python_ver}"
ninja -C build
}
package() {
cd "$pkgname"
# pin to tightly-coupled dependency versions
depends+=( libboost_locale.so
$(_version_constraint openexr 2) # eg: libHalf.so.12
$(_version_constraint openimageio 2) # eg: libOpenImageIO.so.2.0
$(_version_constraint openshadinglanguage 2) # eg: liboslcomp.so.1.10
$(_version_constraint opensubdiv 3) # eg: libosdGPU.so.3.3.3
$(_version_constraint openvdb 2) # eg: libopenvdb.so.6.2
$(_version_constraint python 2) ) # eg: libpython3.6.so.1.0
DESTDIR="${pkgdir}" ninja -C build install
install -Dm755 release/bin/blender-softwaregl "${pkgdir}/usr/bin/blender-softwaregl"
python -m compileall "${pkgdir}/usr/share/blender"
python -O -m compileall "${pkgdir}/usr/share/blender"
install -Dm644 release/freedesktop/org.blender.Blender.appdata.xml "${pkgdir}/usr/share/metainfo/org.blender.Blender.appdata.xml"
}
|
