blob: 7865bf2b329ec34713481975f8d831088406f522 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
|
# Maintainer: Luke Shumaker <lukeshu@parabola.nu>
# Contributor: Joshua Ismael Haase Hernández (xihh) <hahj87@gmail.com>
# Contributor: fauno <fauno@kiwwwi.com.ar>
# Contributor: Márcio Silva <coadde@hyperbola.info>
pkgbase=libretools
pkgname=(libretools librelib gitget)
pkgdesc="Programs for Parabola development"
url="https://git.parabola.nu/packages/libretools.git/"
license=('GPL3' 'GPL2')
pkgver=20240221
source=(https://repo.parabola.nu/other/$pkgname/$pkgname-$pkgver.tar.gz{,.sig}
disable-ronn.patch)
sha256sums=('b0417f7baec944bbc111560ab0b3bb612e487395104f7c4d8913af9d5cb9a834'
'SKIP'
'2ba2b2e048db29a12699ba2de0c023b5cc87035a6f26ee25734a35a490345dbf')
validpgpkeys=('99195DD3BB6FE10A2F36ED8445698744D4FFBFC9' # Luke Shumaker
'BFA8008A8265677063B11BF47171986E4B745536') # Andreas Grapentin
pkgrel=1
arch=('any')
#makedepends=(ruby-ronn-ng)
checkdepends=(
bats
git
'pacman>=5.1.1-1.parabola5' 'pacman<6.1'
expac
openssh
rsync
tokyocabinet
)
prepare() {
cd "$srcdir/$pkgbase-$pkgver"
patch -N -p1 -i $srcdir/disable-ronn.patch
}
build() {
cd "$srcdir/$pkgbase-$pkgver"
make
}
check() {
cd "$srcdir/$pkgbase-$pkgver"
SUDO_USER= make check TESTENVFLAGS='--no-network --no-sudo'
}
package_librelib() {
pkgdesc="The shell library portion of libretools"
license=(GPL2)
conflicts=('xbs')
optdepends=(
'libretools: for libreblacklist/blacklist.sh'
'wget: for libreblacklist/blacklist.sh'
)
cd "$srcdir/$pkgbase-$pkgver"
make install-librelib DESTDIR="$pkgdir"
}
package_gitget() {
pkgdesc="A simple to use downloader for git URLs"
license=(GPL2)
depends=("librelib=$pkgver" git)
provides=("libregit=$pkgver")
conflicts=("libregit")
replaces=("libregit")
cd "$srcdir/$pkgbase-$pkgver"
make install-gitget DESTDIR="$pkgdir"
}
package_libretools() {
backup=(etc/libretools.conf
etc/libretools.d/chroot.conf
etc/libretools.d/libredbdiff.conf
etc/libretools.d/librefetch.conf)
install=libretools.install
conflicts=(devtools libretools-mips64el)
replaces=(libretools-mips64el)
depends=(
"librelib=$pkgver"
"gitget=$pkgver" # `createworkdir`
'pacman>=5.1.1-1.parabola5' 'pacman<6.1'
arch-install-scripts # `mkarchroot` uses `pacstrap`
binutils # `libremakepkg` uses `makepkg` uses `strip`
expac # `libredbdiff`
fakeroot # `libremakepkg` uses `makepkg` uses `fakeroot`
make # `librefetch`
openssh # `librerelease`
rsync # `librerelease` and `makechrootpkg.sh`
'systemd-tools>=234' # systemd-nspawn
tokyocabinet # `toru`
#namcap # Namcap is currently dissabled in libremakepkg :-(
subversion # `diff-unfree`
wget # `aur`, optdepend for librelib:`blacklist`
)
optdepends=(
'qemu-user-static-binfmt: To build ARM packages from x86'
)
cd "$srcdir/$pkgbase-$pkgver"
make install-libretools DESTDIR="$pkgdir"
}
|