blob: 5a8c1eadb3c76ddd832f506fc8f59debc8f8f726 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# $Id: PKGBUILD 192307 2016-10-15 16:13:15Z bgyorgy $
# Maintainer (Arch): Balló György <ballogyor+arch at gmail dot com>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
pkgname=sensors-applet
pkgver=3.0.0
_gitrev=07284262768e3a7066da09845370d78526be6bc1
pkgrel=9.parabola1
pkgdesc="Applet for GNOME Panel to display readings from hardware sensors, including CPU temperature, fan speeds and voltage readings, without nonfree libxnvctrl support"
arch=('i686' 'x86_64')
url="http://sensors-applet.sourceforge.net/"
license=('GPL')
depends=('gnome-panel' 'libatasmart' 'lm_sensors')
makedepends=('git' 'gnome-common' 'intltool' 'yelp-tools')
optdepends=('hddtemp: get HDD temperatures'
'udisks: get HDD temperatures')
source=($pkgname::git://git.code.sf.net/p/sensors-applet/code#commit=$_gitrev)
sha256sums=('SKIP')
prepare() {
cd $pkgname
NOCONFIGURE=1 ./autogen.sh
}
build() {
cd $pkgname
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --libexecdir=/usr/lib/$pkgname
#https://bugzilla.gnome.org/show_bug.cgi?id=656231
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
package() {
cd $pkgname
make DESTDIR="$pkgdir" install
}
|
