blob: 08741db9b440207f46609e790a144d9bcd903982 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
|
# Maintainer (arch): Lukas Fleischer <lfleischer@archlinux.org>
# Contributor: xduugu
# Contributor: nh2
# Contributor: Steven Davidovitz <steviedizzle ð gmail đ com>
# Contributor: Nick B <Shirakawasuna ð gmail đ com>
# Contributor: Christof Musik <christof ð senfdax đ de>
# Contributor: Stefan Rupp <archlinux ð stefanrupp đ de>
# Contributor: Ignas Anikevicius <anikevicius ð gmail đ com>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: Márcio Silva <coadde@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# build order:
# acpi_call-dkms <- acpi_call-lts
# acpi_call
# linux-libre-lts-headers <- acpi_call-lts
# tp_smapi-lts
# linux-libre-headers <- acpi_call
# tp_smapi
#
# these packages may be built as a batch, with the helper script:
# 'scripts/package-all-acpi_call-tp_smapi'
# simply edit '_basekernel' in each # TODO: automate that too
_basekernel=5.15.41
pkgname=tp_smapi-lts
pkgver=0.43
pkgrel=207
pkgrel+=.parabola1.basekernel${_basekernel}
pkgdesc="Modules for ThinkPad's SMAPI functionality"
pkgdesc+=" (for linux-libre-lts)"
arch=('x86_64')
arch+=('i686')
url='https://github.com/evgeni/tp_smapi'
license=('GPL')
makedepends=(linux-libre-lts-headers=${_basekernel} 'git' libelf)
_commit=a63729ab30d85430048f65c37f29188ab484cd52 # tags/tp-smapi/0.43
source=("git+https://github.com/evgeni/tp_smapi#commit=$_commit")
sha256sums=('SKIP')
pkgver() {
cd tp_smapi
git describe --tags | sed 's/^tp-smapi\///;s/-/+/g'
}
build() {
cd tp_smapi
# https://bugs.archlinux.org/task/54975 (kernel has no _GLOBAL_OFFSET_TABLE_):
# Clear EXTRA_CFLAGS since it defaults to injecting CFLAGS and -fno-plt breaks the modules
make HDAPS=1 KVER="$(</usr/src/linux-libre-lts/version)" EXTRA_CFLAGS=
}
package() {
depends=(linux-libre-lts=${_basekernel})
local extradir=/usr/lib/modules/$(</usr/src/linux-libre-lts/version)/extramodules
cd tp_smapi
# install kernel modules
find . -name "*.ko" -exec install -Dt "$pkgdir$extradir" {} +
# compress kernel modules
find "$pkgdir" -name "*.ko" -exec xz {} +
# load module on startup
echo tp_smapi | install -Dm644 /dev/stdin "$pkgdir/usr/lib/modules-load.d/$pkgname.conf"
}
|