blob: 714f60f9940a7c37a3dc99910fc73ba9cf154650 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# Maintainer (Arch): Ray Rashif <schiv@archlinux.org>
# Contributor (Arch): Mateusz Herych <heniekk@gmail.com>
# Contributor (Arch): Charles Lindsay <charles@chaoslizard.org>
# Contributor (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Contributor (Hyperbola): Márcio Silva <coadde@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
_basekernel=5.5.13-1
pkgbase=vhba-module
pkgname=(vhba-module vhba-module-dkms)
pkgver=20200106
pkgrel=26
pkgrel+=.parabola1.basekernel${_basekernel%-*}
pkgdesc="Kernel module that emulates SCSI devices"
pkgdesc+=" (built for the linux-libre kernel package)"
url="https://cdemu.sourceforge.io/"
arch=(x86_64)
arch+=(i686 armv7h)
license=(GPL)
makedepends=(linux-libre-headers=${_basekernel%-*} git libelf)
source=("https://downloads.sourceforge.net/cdemu/$pkgbase-$pkgver.tar.bz2"
60-vhba.rules dkms.conf)
sha256sums=('59a3208a7b8fcf1bb03bd4d352ec89d06a8b6b84db325e31b0863b209dde3483'
'3052cb1cadbdf4bfb0b588bb8ed80691940d8dd63dc5502943d597eaf9f40c3b'
'8cab0ebb4fee72069d63616b0983f105b98d1261e72e9bef5509a6e60bc382a7')
prepare() {
cd $pkgbase-$pkgver
sed -i 's/20190302/20190410/' Makefile # Fixup VHBA_VERSION
}
build() {
cd $pkgbase-$pkgver
make KERNELRELEASE="$(</usr/src/linux-libre/version)"
}
package_vhba-module() {
depends=(linux-libre=${_basekernel%-*})
local extradir="/usr/lib/modules/$(</usr/src/linux-libre/version)/extramodules"
cd $pkgbase-$pkgver
install -Dt "$pkgdir$extradir" -m644 *.ko
install -Dt "$pkgdir/usr/lib/udev/rules.d" -m644 ../60-vhba.rules
echo 'g cdemu - -' | install -Dm644 /dev/stdin "$pkgdir/usr/lib/sysusers.d/cdemu.conf"
find "$pkgdir" -name '*.ko' -exec xz {} +
}
package_vhba-module-dkms() {
depends=(dkms)
provides=("vhba-module=$pkgver-${pkgrel%%.*}")
conflicts=(vhba-module)
cd $pkgbase-$pkgver
install -Dt "$pkgdir/usr/src/$pkgbase-$pkgver" -m644 Makefile vhba.c ../dkms.conf
install -Dt "$pkgdir/usr/lib/udev/rules.d" -m644 ../60-vhba.rules
echo 'g cdemu - -' | install -Dm644 /dev/stdin "$pkgdir/usr/lib/sysusers.d/cdemu.conf"
}
# vim:set ts=2 sw=2 et:
|
