blob: a8132f9d6a662114822c297e3fdf57e993dd1fce (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
|
# Maintainer: Luke Shumaker <lukeshu@parabola.nu>
# Maintainer: David P. <megver83@parabola.nu>
# Contributor: Joshua Ismael Haase Hernández (xihh) <hahj87@gmail.com>
# Contributor: fauno <fauno@kiwwwi.com.ar>
# Contributor: Márcio Silva <coadde@hyperbola.info>
# Contributor: bill-auger <bill-auger@programmer.net>
pkgbase=libretools
pkgname=(libretools librelib gitget)
pkgver=20190907
_pacman_constraints=( 'pacman<6.2' )
pkgrel=1
pkgrel+=.nonsystemd3
pkgdesc="Programs for Parabola development"
arch=('any')
url="https://git.parabola.nu/packages/libretools.git/"
# license=(GPL-2.0-only GPL-3.0-or-later) # TODO:
license=('GPL2' 'GPL3')
makedepends=(ruby-ronn-ng)
checkdepends=(
bats
git
"${_pacman_constraints[@]}"
expac
openssh
rsync
tokyocabinet
)
source=(https://repo.parabola.nu/other/$pkgname/$pkgname-$pkgver-nonsystemd.tar.gz{,.sig})
source+=(0001-revert.patch
0002-libremakepkg-pacman_5_2.patch)
sha256sums=('c9bdc6f422234b6b260349e488266500756857bbb65079783aa5e997b6a2d410'
'SKIP')
sha256sums+=('108aa8bbfb1ffe96427540cd8f7788338883b08ad038b2ed426e93ac6c57e91b'
'8986adf14a81b979b2ff4c4e3e76483115c146782e4ba30640649299f98355df')
validpgpkeys=('99195DD3BB6FE10A2F36ED8445698744D4FFBFC9' # Luke Shumaker
'6DB9C4B4F0D8C0DC432CF6E4227CA7C556B2BA78' # David P.
'BFA8008A8265677063B11BF47171986E4B745536' # Andreas Grapentin
'3954A7AB837D0EA9CFA9798925DB7D9B5A8D4B40') # bill-auger
prepare() {
cd "$srcdir"/$pkgbase-$pkgver-nonsystemd
patch -N -p1 -i $srcdir/revert.patch
patch -N -p1 -i $srcdir/0002-libremakepkg-pacman_5_2.patch
}
build() {
cd "$srcdir"/$pkgbase-$pkgver-nonsystemd
make
}
check() {
cd "$srcdir"/$pkgbase-$pkgver-nonsystemd
# <= 20240327
# SUDO_USER= make check TESTENVFLAGS='--no-network --no-sudo'
# >= 20240403
# SUDO_USER= make check BATS_FLAGS='--filter-tags !network,!sudo'
}
package_librelib() {
pkgdesc="The shell library portion of libretools"
license=(GPL2)
conflicts=('xbs')
optdepends=(
'libretools: for libreblacklist/blacklist.sh'
'wget: for libreblacklist/blacklist.sh'
)
cd "$srcdir"/$pkgbase-$pkgver-nonsystemd
make install-librelib DESTDIR="$pkgdir"
}
package_gitget() {
pkgdesc="A simple to use downloader for git URLs"
license=(GPL2)
depends=("librelib=$pkgver" git)
cd "$srcdir"/$pkgbase-$pkgver-nonsystemd
make install-gitget DESTDIR="$pkgdir"
}
package_libretools() {
backup=(etc/libretools.conf
etc/libretools.d/chroot.conf
etc/libretools.d/libredbdiff.conf
etc/libretools.d/librefetch.conf)
install=libretools.install
conflicts=(devtools)
depends=(
arch-install-scripts # `mkarchroot` uses `pacstrap`
binutils # `libremakepkg`->`makepkg` uses `strip`
expac # `libredbdiff`
fakeroot # `libremakepkg`->`makepkg` uses `fakeroot`
make # `librefetch`
openssh # `librerelease`
pacutils # `librechroot` uses `pacsift`
rsync # `librerelease` and `makechrootpkg.sh`
tokyocabinet # `toru`
namcap # `libremakepkg`
subversion # `diff-unfree`
wget # `aur`, optdepend for librelib:`blacklist`
)
depends+=( # pinned dependencies
"librelib=$pkgver"
"gitget=$pkgver" # `createworkdir`
"${_pacman_constraints[@]}"
)
depends=( ${depends[*]/pacutils/} ) # WIP
depends=( ${depends[*]/namcap/} ) # FIXME: Namcap is currently disabled in libremakepkg :-(
optdepends=(
'qemu-user-static-binfmt: To build ARM packages from x86'
)
cd "$srcdir"/$pkgbase-$pkgver-nonsystemd
make install-libretools DESTDIR="$pkgdir"
}
|