blob: 0d1ee60238fab14ed2d57bae34e6e8fc6e146e42 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
|
# Maintainer: David P. <megver83@parabola.nu>
# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Maintainer (Arch): Antonio Rojas <arojas@archlinux.org>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>
pkgname=sddm
pkgver=0.21.0
pkgrel=4
pkgrel+=.nonsystemd1
pkgdesc='QML based X11 and Wayland display manager'
arch=(x86_64)
arch+=(i686 armv7h)
url='https://github.com/sddm/sddm'
license=(GPL-2.0-only)
depends=(bash
gcc-libs
glibc
libelogind
libxau
libxcb
pam
qt6-base
qt6-declarative
ttf-font
xorg-server
xorg-xauth)
makedepends=(extra-cmake-modules
python-docutils
qt5-base
qt5-declarative
qt5-tools
qt6-tools)
optdepends=('qt5-declarative: for using Qt5 themes')
backup=('usr/share/sddm/scripts/Xsetup'
'usr/share/sddm/scripts/Xstop'
'etc/pam.d/sddm'
'etc/pam.d/sddm-autologin'
'etc/pam.d/sddm-greeter')
provides=(display-manager)
source=(https://github.com/$pkgname/$pkgname/archive/v$pkgver/$pkgname-$pkgver.tar.gz
sddm.{tmpfiles,sysusers})
sha256sums=('f895de2683627e969e4849dbfbbb2b500787481ca5ba0de6d6dfdae5f1549abf'
'db625f2a3649d6d203e1e1b187a054d5c6263cadf7edd824774d8ace52219677'
'9fce66f325d170c61caed57816f4bc72e9591df083e89da114a3bb16b0a0e60f')
build() {
cmake -B build -S $pkgname-$pkgver \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_INSTALL_LIBEXECDIR=/usr/lib/sddm \
-DBUILD_WITH_QT6=ON \
-DDBUS_CONFIG_DIR=/usr/share/dbus-1/system.d \
-DDBUS_CONFIG_FILENAME=sddm_org.freedesktop.DisplayManager.conf \
-DBUILD_MAN_PAGES=ON \
-DUSE_ELOGIND=yes \
-DNO_SYSTEMD=yes \
-DUID_MAX=60513
cmake --build build
cmake -B build5 -S $pkgname-$pkgver \
-DCMAKE_INSTALL_PREFIX=/usr
cmake --build build5/src/greeter
cmake --build build5/components
}
package() {
DESTDIR="$pkgdir" cmake --install build
DESTDIR="$pkgdir" cmake --install build5/src/greeter
DESTDIR="$pkgdir" cmake --install build5/components
install -d "$pkgdir"/usr/lib/sddm/sddm.conf.d
"$pkgdir"/usr/bin/sddm --example-config > "$pkgdir"/usr/lib/sddm/sddm.conf.d/default.conf
# Don't set PATH in sddm.conf
sed -r 's|DefaultPath=.*|DefaultPath=/usr/local/sbin:/usr/local/bin:/usr/bin|g' -i "$pkgdir"/usr/lib/sddm/sddm.conf.d/default.conf
# Unset InputMethod https://github.com/sddm/sddm/issues/952
sed -e "/^InputMethod/s/qtvirtualkeyboard//" -i "$pkgdir"/usr/lib/sddm/sddm.conf.d/default.conf
install -Dm644 sddm.sysusers "$pkgdir"/usr/lib/sysusers.d/sddm.conf
install -Dm644 sddm.tmpfiles "$pkgdir"/usr/lib/tmpfiles.d/sddm.conf
}
|
