blob: 6de26b69be23559f0dc80eea697dad5a67332b99 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Maintainer (aur): Roshless <pkg@roshless.com>
# Maintainer: Iván Ávalos <avalos@disroot.org>
# Contributor: bill-auger <bill-auger@programmer.net>
# Contributor: Wael Karram <wael@waelk.tech>
pkgname=lagrange
pkgrel=1
pkgver=1.17.6
pkgdesc="Beautiful Gemini Client"
url="https://gmi.skyjake.fi/lagrange/"
arch=('x86_64' 'i686' 'aarch64' 'armv7h')
license=("BSD2")
source=("https://git.skyjake.fi/skyjake/$pkgname/releases/download/v$pkgver/lagrange-$pkgver.tar.gz")
sha256sums=('b9d0982617fec495565ac9c09fb788a0be207d6fdf2324edc390e5cac8b1523b')
depends=(
"fribidi"
"harfbuzz"
"hicolor-icon-theme"
"libunistring"
"openssl"
"pcre"
"sdl2"
)
optdepends=("mpg123")
makedepends=("cmake" "zip")
prepare() {
cd "$srcdir"/$pkgname-$pkgver
# delete vendored libs - use system libs instead
rm -rf lib/fribidi/
rm -rf lib/harfbuzz/
}
build() {
cmake -B build -S "$pkgname-${pkgver}" \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX='/usr' \
-DENABLE_KERNING=OFF \
-DTFDN_ENABLE_WARN_ERROR=OFF \
-DENABLE_FRIBIDI_BUILD=OFF \
-DENABLE_HARFBUZZ_MINIMAL=OFF \
-Wno-dev
make -C build
}
package() {
install -Dm644 $pkgname-$pkgver/LICENSE.md "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
cd build
make DESTDIR="$pkgdir" install
}
|
