blob: 42b9c75ab256714e30084b209fd457c4a3fafe7e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
# Maintainer (arch): speps <speps at aur dot archlinux dot org>
# Contributor: farid abdelnour <farid at archlinux-br.org>
# Contributor: DonVla <donvla@users.sourceforge.net>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor: bill-auger <bill-auger@programmer.net>
pkgname=minicomputer
pkgver=1.41
pkgrel=4
pkgdesc="Software synthesizer for creating experimental electronic sounds"
arch=('i686' 'x86_64') # no arm - requires SSE
url="http://minicomputer.sourceforge.net"
license=('GPL3')
depends=('fltk' 'jack' 'liblo')
makedepends=('scons')
install="$pkgname.install"
source=("http://downloads.sourceforge.net/sourceforge/$pkgname/MinicomputerV$pkgver.tar.gz"
"$pkgname.desktop")
source+=(print.patch)
md5sums=('d2524f5fee7475159292e29a5bcd73d2'
'3cc74321d55870b1684767255c74c2f8')
md5sums+=('ed8548394b3dcf1823c047fd7e9fcf9e')
prepare() {
# installpresets.sh fix
sed -i "s|factory|/usr/share/$pkgname/&|g" installpresets.sh
# DSO linking fix
sed -i "35aenv.Append(LIBS = ['m'])" -i SConstruct
# missing includes
sed -i '30a#include <unistd.h>' editor/Memory.h
# fix 'print' commands in scons file
patch -Np1 < print.patch
}
build() {
scons
}
package() {
# bin
install -d "$pkgdir/usr/bin"
install -Dm755 "$pkgname"{,CPU} "$pkgdir/usr/bin"
# icon
install -Dm644 $pkgname.xpm \
"$pkgdir/usr/share/pixmaps/$pkgname.xpm"
# desktop file
install -Dm644 $pkgname.desktop \
"$pkgdir/usr/share/applications/$pkgname.desktop"
# presets
install -d "$pkgdir/usr/share/$pkgname/factoryPresets"
install -Dm644 factoryPresets/* "$pkgdir/usr/share/$pkgname/factoryPresets"
# doc
install -Dm644 "$pkgname"Manual.pdf \
"$pkgdir/usr/share/doc/$pkgname/Manual.pdf"
# presets installer script
install -Dm755 installpresets.sh \
"$pkgdir/usr/share/$pkgname/installpresets.sh"
}
|