blob: b4c8cbec2aeb3883dcb8f2399ba28515c96552ef (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
# Maintainer (aur): Carsten Feuls <archlinux@carstenfeuls.de>
# Contributor: AXVill
# Contributor: dacoit <dacoit at tuta.io>
# Contributor: xjpvictor Huang <ke [AT] xjpvictor [DOT] info>
# Contributor: uuwe
# parabola changes and rationale:
# - removed "open source" term from pkgdesc
pkgname=openswan
pkgver=2.6.49.1
pkgrel=1
pkgdesc='A libre implementation of IPsec for the Linux operating system'
url='https://www.openswan.org'
arch=('i686' 'x86_64' 'armv7h')
license=('GPL' 'custom')
depends=('gmp' 'perl' 'iproute2')
makedepends=('flex' 'bison')
optdepends=('python2')
conflicts=('ipsec-tools')
options=('!makeflags')
backup=('etc/ipsec.conf'
'etc/ipsec.d/policies/'{block,clear,clear-or-private,private,private-or-clear})
source=("http://download.openswan.org/openswan/openswan-${pkgver}.tar.gz"
'openswan.service')
prepare() {
cd "$pkgname-$pkgver"
# Change install paths to Arch defaults
sed -i 's|/usr/local|/usr|;s|libexec/ipsec|lib/openswan|;s|)/sbin|)/bin|' Makefile.inc
# Replace invalid init script paths with systemd script path
sed -i 's/^INC_RCDIRS.*/INC_RCDIRS\?\=\/usr\/lib\/systemd\/scripts/' Makefile.inc
}
build() {
cd "$pkgname-$pkgver"
make USE_XAUTH=true USE_OBJDIR=true programs
}
package() {
cd "$pkgname-$pkgver"
# Pre-create init script directory
mkdir -p "$pkgdir/usr/lib/systemd/scripts"
make DESTDIR="$pkgdir" install
# Change permissions in /var
mv "$pkgdir/var/run" "$pkgdir/"
rm -r "$pkgdir/var"
chmod 700 "$pkgdir/run/pluto"
# Copy License
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/openswan/LICENSE"
# Install service unit
install -Dm644 "$srcdir/openswan.service" "$pkgdir/usr/lib/systemd/system/openswan.service"
# fix manpages
mv "$pkgdir/usr/man" "$pkgdir/usr/share/"
# fix python2
sed -i '1s|python|python2|' "$pkgdir/usr/lib/openswan/verify"
}
sha512sums=('9e6c03aa5f5ed7338473bfd6b9b2740f928ac38775149f90519181b6b9ef95fcb1af68ea737554dd11d2faef22a71458171fff9d0566bb115096a04b03395e76'
'a234e97a4fe10fb85a8a1b69d0b55b7c7a4a9ef44c199f876f64bb7290e9f161b20e4c721112e26c6a5636a898a27a36b525aae0944cf6217ff81c36389d5803')
|
