blob: f3fbcecafeca15766b608afb3e3f9798faf5496f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: Javier Torres <javitonino [at] gmail [dot] com>
pkgname=softhsm
pkgver=1.3.4
pkgrel=1
pkgdesc="Software PKCS11 store"
arch=('i686' 'x86_64')
url="http://www.opendnssec.org/softhsm/"
license=('custom' 'BSD')
depends=('botan' 'sqlite3')
backup=("etc/softhsm.conf")
source=("http://www.opendnssec.org/files/source/${pkgname}-${pkgver}.tar.gz"{,.sig})
sha1sums=('f09b6828776bcf9fef1dd46cfa7a495da01c7747'
'SKIP')
sha256sums=('f10319dfa651023dad3d0845d284ec08ef982c1fc1bdb55cf8a725f762961e97'
'SKIP')
prepare() {
cd "${srcdir}/${pkgname}-${pkgver}"
# /usr/lib/softhsm -> /usr/bin (no subdirectory)
sed -i \
-e "s/full_libdir=\"\$full_libdir\/softhsm\"/#full_libdir=\"\$full_libdir\/softhsm\"/" \
-e "s/libdir=\$full_libdir/#libdir=\$full_libdir/" \
configure
}
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
./configure --prefix=/usr \
--sbindir=/usr/bin \
--datarootdir=/usr/share \
--localstatedir=/var/lib \
--sysconfdir=/etc \
--with-botan=/usr
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}/" install
install -Dm0644 "LICENSE" \
"${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|
