blob: 1267ab4ad6da7287471460b6a909643215d57078 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
|
# SPDX-License-Identifier: CC0-1.0
# Maintainer: Parabola Hackers <dev@lists.parabola.nu>
# NOTE: This PKGBUILD does not need to be edited manually.
# The package is normally built automatically by autobuilder.
# To generate a new keyring, simply push a new commit to hackers.git.
# eg: $ git commit --allow-empty --message=rebuild
# $ git push parabola master
# The autobuilder will modify this PKGBUILD,
# replacing $pkgver and $_gitver,
# build and publish the package,
# and commit the modified PKGBUILD to abslibre.
pkgname=parabola-keyring
pkgver=20221105
_gitver=374d9b5b110ddfe715419b10caa4de2972aed162
pkgrel=1
pkgdesc="Parabola GNU/Linux-libre PGP keyring"
arch=(any)
url=https://wiki.parabola.nu/Parabola_Keyring
license=(GPL)
makedepends=(git parabola-hackers)
makedepends=( ${makedepends[*]/parabola-hackers/parabola-hackers>=20220802-1} ) # in libre-testing
install=$pkgname.install
source=(hackers-${_gitver}::git://git.parabola.nu/hackers.git#commit=${_gitver})
sha512sums=('SKIP')
prepare()
{
# network check
# NOTE: this is the only parabola PKGBUILD, which requires internet access in the build chroot
# the pacman-make-keyring procedure was originally in a mksource() function,
# presumably for that reason; but that o/c removed the requirement only from users
# TODO: it would be great to re-implement this, so that it does not
# there is a WIP on the parabola-hackers.git 'wip-import-keys-from-hackers-git' branch
local net_check_url=https://repo.parabola.nu/check_network_status.txt
local net_err_msg="ERROR: this PKGBUILD requires internet access in the build chroot"
curl ${net_check_url} &> /dev/null || ! echo "${net_err_msg}" || return 1
}
build()
{
mv {,.}hackers-${_gitver}
mkdir .cachedir
export PARABOLA_HACKERS_YAMLDIR="${PWD}"/.hackers-${_gitver}/users
# NOTE: the current 'parabola-hackers' package does not yet recognize
# the 'keyserver' env-var - the keyserver is still hard-coded;
# and it is now invalid - 'parabola-hackers' must be rebuilt for this;
# but that build currently has a problem - the autobuilder handles
# this now, via an un-published kludge in the autobuild.sh script
# TODO: remove this note and the version constraint,
# after 'parabola-hackers' has been rebuilt
# NOTE: the rebuilt 'parabola-hackers' is now in [libre-testing]
/usr/lib/parabola-hackers/pacman-make-keyring \
V=${pkgver} \
keyserver=hkp://pgp.cyberbits.eu:11371 \
cachedir="${PWD}/.cachedir"
}
package()
{
bsdtar xf ${pkgname}-${pkgver}.tar.gz
cd ${pkgname}-${pkgver}
make PREFIX=/usr DESTDIR="${pkgdir}" install
}
|