blob: eed428b6df9e4cd4c466077893a5fe048ce81453 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
|
# $Id: PKGBUILD 204755 2014-01-26 12:16:01Z andyrtr $
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
pkgname=gnome-color-manager
pkgver=3.10.1
pkgrel=2
pkgdesc="Color profile manager for the GNOME desktop"
arch=(i686 x86_64)
url="http://projects.gnome.org/gnome-color-manager/"
license=(GPL2)
depends=(libcanberra vte3 exiv2 hicolor-icon-theme desktop-file-utils clutter-gtk
mash shared-color-profiles shared-color-targets gnome-desktop colord-gtk libexif)
makedepends=(intltool yelp-tools)
install=gnome-color-manager.install
options=('!emptydirs')
groups=('gnome-extra')
source=(http://ftp.gnome.org/pub/GNOME/sources/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.xz)
sha256sums=('2944627f4166aaac08ba9d73614cbd79eba93573bd7d32e17a12082e30fb1399')
build(){
cd $pkgname-$pkgver
# man pages need docbook-sgml, which we don't have
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
--libexecdir=/usr/lib/gnome-color-manager --disable-static --disable-man-pages
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0 /g' -e 's/ if test "$export_dynamic" = yes && test -n "$export_dynamic_flag_spec"; then/ func_append compile_command " -Wl,-O1,--as-needed"\n func_append finalize_command " -Wl,-O1,--as-needed"\n\0/' libtool
make
}
package() {
cd $pkgname-$pkgver
make DESTDIR="$pkgdir" install
}
|
