blob: 0abaf3bf88f01b33eadef335e0106681f2e4f328 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# $Id: PKGBUILD 116062 2014-07-21 11:15:13Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer: Daniel Micay <danielmicay@gmail.com>
# Contributor: Bartłomiej Piotrowski <nospam@bpiotrowski.pl>
# Contributor: Patrick Leslie Polzer <leslie.polzer@gmx.net>
# Contributor: cdhotfire <cdhotfire@gmail.com>
# Contributor: Shinlun Hsieh <yngwiexx@yahoo.com.tw>
# Contributor: Elisamuel Resto <ryuji@simplysam.us>
pkgname=chrony
pkgver=1.30
pkgrel=3
pkgdesc='Lightweight NTP client and server'
arch=('i686' 'x86_64')
url="http://chrony.tuxfamily.org/"
options=(strip emptydirs)
license=('GPL')
depends=('readline' 'libcap')
backup=('etc/chrony.conf')
source=(http://download.tuxfamily.org/chrony/${pkgname}-${pkgver}.tar.gz
service)
install=${pkgname}.install
sha256sums=('43aca956a0beb2c4847feffc847fec2c429ee9afb6252c7a499bbd68933046dd'
'3c9d05aaba6c0bef43fd1923a6dd7ac5f9b9539d21efbd1fbe592b54dec8d493')
build() {
cd $pkgname-$pkgver
./configure --prefix=/usr
make
}
package() {
cd $pkgname-$pkgver
make DESTDIR="$pkgdir" install install-docs
install -Dm0644 "$srcdir/$pkgname-$pkgver/examples/chrony.conf.example" "$pkgdir/etc/chrony.conf"
echo -e "\n# Enable kernel RTC sync\nrtcsync" >> "$pkgdir/etc/chrony.conf"
sed -i '/^! rtconutc$/ s/^! //' "$pkgdir/etc/chrony.conf"
mv "$pkgdir/usr/sbin/chronyd" "$pkgdir/usr/bin"
rmdir "$pkgdir/usr/sbin"
install -Dm644 "$srcdir/service" "$pkgdir/usr/lib/systemd/system/chrony.service"
install -dm755 "$pkgdir/usr/lib/systemd/ntp-units.d"
echo "$pkgname.service" > "$pkgdir/usr/lib/systemd/ntp-units.d/10-$pkgname.list"
chown 183:183 "$pkgdir/var/lib/chrony"
}
|
