blob: c6723e21717d86cce957c5680accb1f4a5179d61 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
|
# $Id: PKGBUILD 112600 2014-06-04 13:50:53Z bluewind $
# Maintainer: Gaetan Bisson <bisson@archlinux.org>
# Contributor: Gerhard Brauer <gerhard.brauer@web.de>
pkgname=collectd
pkgver=5.4.1
pkgrel=3
pkgdesc='Daemon which collects system performance statistics periodically'
url='http://collectd.org/'
arch=('i686' 'x86_64')
license=('GPL')
optdepends=('curl: apache, ascent, curl, nginx, and write_http plugins'
'libdbi: dbi plugin'
'libesmtp: notify_email plugin'
'libgcrypt: encryption and authentication for network plugin'
'libmemcached: memcachec plugin'
'libmariadbclient: mysql plugin'
'iproute2: netlink plugin'
'net-snmp: snmp plugin'
'libnotify: notify_desktop plugin'
'liboping: ping plugin'
'libpcap: dns plugin'
'perl: perl plugin'
'postgresql-libs: postgresql plugin'
'python2: python plugin'
'rrdtool: rrdtool and rrdcached plugins'
'lm_sensors: lm_sensors and sensors plugins'
'libvirt: libvirt plugin'
'libxml2: ascent and libvirt plugins'
'yajl: curl_json plugin')
makedepends=('curl' 'libdbi' 'libesmtp' 'libgcrypt' 'libmemcached'
'libmariadbclient' 'iproute2' 'net-snmp' 'libnotify' 'liboping'
'libpcap' 'postgresql-libs' 'python2' 'rrdtool' 'lm_sensors'
'libvirt' 'libxml2' 'yajl')
depends=('libltdl' 'iptables')
source=("${url}files/${pkgname}-${pkgver}.tar.bz2"
'libperl.patch'
'service')
sha1sums=('cea47e3936ed081bd71efacf7ba825fc837dc347'
'efa6450c20ce314e9000a69b17520211f6a471e1'
'04f676d0b76c34df0bbf94629813e035b1febe04')
backup=('etc/collectd.conf')
prepare() {
cd "${srcdir}/${pkgname}-${pkgver}"
sed 's/-Werror//g' -i *.ac */*.{am,in} */*/*.{am,in}
patch -p1 -i ../libperl.patch
autoreconf
}
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--localstatedir=/var \
--sbindir=/usr/bin \
--with-python=/usr/bin/python2
make all
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
rmdir "${pkgdir}/var/run" # FS#30201
install -Dm644 ../service "${pkgdir}"/usr/lib/systemd/system/collectd.service
install -Dm644 contrib/collectd2html.pl "${pkgdir}"/usr/share/collectd/collectd2html.pl
}
|
