blob: c9cd5a61ea3fa02b6a013ee10fc45c307ae6218d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# $Id: PKGBUILD 108867 2014-04-05 22:02:16Z anatolik $
# Maintainer: Anatol Pomozov <anatol.pomozov@gmail.com>
# Contributor: Filip Brcic <brcha@gna.org>
# Contributor: Mika Fischer <mika.fischer@zoopnet.de>
# Contributor: Gergely Imreh <imrehgATgmailDOTcom>
pkgname=ninja
pkgver=1.4.0
pkgrel=1
pkgdesc='Small build system with a focus on speed'
arch=(i686 x86_64)
url='http://martine.github.io/ninja/'
license=(Apache)
depends=(gcc-libs)
makedepends=(asciidoc python2 re2c python2 emacs-nox)
checkdepends=(gtest)
source=(https://github.com/martine/ninja/archive/v$pkgver.zip)
sha1sums=('5de3dcd1564056f4f350d99f950f581214893a05')
build() {
cd ninja-$pkgver
python2 ./bootstrap.py
emacs -Q --batch -f batch-byte-compile misc/ninja-mode.el
asciidoc doc/manual.asciidoc
}
check() {
cd ninja-$pkgver
python2 ./configure.py --with-gtest=/usr/src/gtest
./ninja ninja_test
./ninja_test --gtest_filter=-SubprocessTest.SetWithLots
}
package() {
cd ninja-$pkgver
install -m755 -D ninja "$pkgdir/usr/bin/ninja"
install -m644 -D doc/manual.asciidoc "$pkgdir/usr/share/doc/ninja/manual.asciidoc"
install -m644 -D doc/manual.html "$pkgdir/usr/share/doc/ninja/manual.html"
install -m644 -D misc/ninja-mode.el "$pkgdir/usr/share/emacs/site-lisp/ninja-mode.el"
install -m644 -D misc/ninja-mode.elc "$pkgdir/usr/share/emacs/site-lisp/ninja-mode.elc"
install -m644 -D misc/bash-completion "$pkgdir/usr/share/bash-completion/completions/ninja"
install -m644 -D misc/zsh-completion "$pkgdir/usr/share/zsh/site-functions/_ninja"
}
|