1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# $Id: PKGBUILD 116398 2014-07-26 17:46:00Z fyan $
# Maintainer: Felix Yan <felixonmars@gmail.com>
# Contributor: Caleb Maclennan <caleb@alerque.com>
# Contributor: Shanto <shanto@hotmail.com>
# Contributor: Athurg <athurg@gooth.cn>
# Contributor: TDY <tdy@gmx.com>
pkgname=shutter
pkgver=0.91
pkgrel=2
pkgdesc="a featureful screenshot tool (formerly gscrot)"
arch=('i686' 'x86_64')
url="http://shutter-project.org/"
license=('GPL3')
depends=(xdg-utils libxml-perl imagemagick bc procps librsvg gnome-perl
perl-{gnome2-wnck,gtk2-{imageview,unique},x11-protocol,image-exiftool}
perl-{proc-{simple,processtable},net-{dbus,dropbox-api},goo-canvas}
perl-{sort-naturally,json,json-xs,xml-simple,www-mechanize,locale-gettext}
perl-{file-{which,basedir,copy-recursive},path-class})
optdepends=('nautilus-sendto: "Send To" functionality in right-click and main menu'
'gnome-web-photo: Support for capturing websites')
#'perl-gtk2-appindicator: AppIndicator support')
source=("http://shutter-project.org/wp-content/uploads/releases/tars/$pkgname-$pkgver.tar.gz")
prepare() {
cd "$srcdir/$pkgname-$pkgver"
# Fix tray icon under many icon themes, from Gentoo
sed -e "/\$tray->set_from_icon_name/s:set_from_icon_name:set_from_file:" \
-e "s:shutter-panel:/usr/share/icons/hicolor/scalable/apps/&.svg:" \
-i bin/shutter
}
package() {
cd "$srcdir/$pkgname-$pkgver"
install -Dm755 bin/$pkgname "$pkgdir/usr/bin/$pkgname"
cp -a share "$pkgdir/usr/"
}
md5sums=('9775b904dd4e75b87f5e51bb861c74ad')
|
