blob: 0a68d21beb2b391400222867e731530d0cd1e89d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# $Id: PKGBUILD 215177 2014-06-15 15:40:57Z heftig $
# Maintainer: Daniel Isenmann <daniel [at] archlinux.org>
# Contributor: dorphell <dorphell@gmx.net>
pkgname=gc
pkgver=7.4.2
pkgrel=1
pkgdesc="A garbage collector for C and C++"
arch=('i686' 'x86_64')
url="http://www.hboehm.info/gc/"
license=('GPL')
source=("http://www.hboehm.info/gc/gc_source/${pkgname}-${pkgver}.tar.gz")
depends=('gcc-libs' 'libatomic_ops')
md5sums=('12c05fd2811d989341d8c6d81f66af87')
prepare() {
cd ${pkgname}-${pkgver}
sed -i 's#pkgdata#doc#' doc/doc.am
}
build() {
cd ${pkgname}-${pkgver}
autoreconf -fi
./configure --prefix=/usr --enable-cplusplus --disable-static
make
}
check() {
cd ${pkgname}-${pkgver}
make check
}
package() {
cd ${pkgname}-${pkgver}
make DESTDIR="${pkgdir}" install
sed -i -e 's/GC_MALLOC 1L/gc 3/' doc/gc.man
install -m755 -d "${pkgdir}/usr/share/man/man3"
install -m644 doc/gc.man "${pkgdir}/usr/share/man/man3/gc.3"
}
|
