blob: fcd3d62e81062b3aa6b36c98f4ce5c3e99a84804 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# $Id: PKGBUILD 212356 2014-05-13 22:00:54Z jgc $
# Maintainer: Ionut Biru <ibiru@archlinux.org>
pkgname=gcr
pkgver=3.12.2
pkgrel=1
pkgdesc="A library for bits of crypto UI and parsing"
arch=(i686 x86_64)
url="http://www.gnome.org"
license=('GPL2')
depends=('dconf' 'desktop-file-utils' 'gtk3' 'hicolor-icon-theme' 'libgcrypt'
'p11-kit')
makedepends=('intltool' 'gobject-introspection' 'python' 'vala' 'libxslt')
options=('!makeflags')
install=gcr.install
source=(http://download.gnome.org/sources/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.xz
10-gcr.conf)
sha256sums=('456e20615ab178aa92eeabdea64dcce535c10d5af189171d9375291a2447d21c'
'5f2eda7175ae9f23ee0e09d2beceb24fd2f6daafd7bddfcc1c1f5a3734eb60fc')
build() {
cd "$pkgname-$pkgver"
./configure --prefix=/usr \
--libexec=/usr/lib/gcr \
--disable-static \
--disable-update-mime \
--disable-schemas-compile
make
}
package() {
cd "$pkgname-$pkgver"
make DESTDIR="$pkgdir" install
# gcr wants to lock some memory to prevent swapping out private keys
# https://bugs.archlinux.org/task/32616
# https://bugzilla.gnome.org/show_bug.cgi?id=688161
install -Dm644 ../10-gcr.conf "$pkgdir/etc/security/limits.d/10-gcr.conf"
}
# vim:set ts=2 sw=2 et:
|
