blob: dd11cd1f50c80ab4b09c3d42260c6cce651ab315 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# $Id: PKGBUILD 209698 2014-04-01 14:02:33Z jgc $
# Maintainer: Jan de Groot <jgc@archlinux.org>
pkgbase=gnome-desktop-sharp
pkgname=('gnome-desktop-sharp' 'libgnome-desktop-sharp' 'gtksourceview2-sharp' 'rsvg2-sharp' 'vte-sharp' 'wnck-sharp')
pkgver=2.26.0
pkgrel=10
arch=('i686' 'x86_64')
license=(LGPL)
url="http://gtk-sharp.sourceforge.net"
makedepends=('gnome-sharp' 'gnome-desktop2' 'vte' 'librsvg' 'libwnck' 'gtksourceview2' 'monodoc')
source=(http://ftp.gnome.org/pub/gnome/sources/$pkgname/${pkgver:0:4}/$pkgname-$pkgver.tar.bz2
gnome-desktop-sharp-lib-target.patch)
md5sums=('4bc990900bb318b2ba0b0e7998bb47d1'
'980cd3adf5e745f4caee0a172a51dcc3')
build() {
export MONO_SHARED_DIR="$srcdir/wapi"
mkdir -p "$MONO_SHARED_DIR"
cd $pkgname-$pkgver
patch -Np1 -i $srcdir/gnome-desktop-sharp-lib-target.patch
./configure --prefix=/usr --sysconfdir=/etc --disable-static
make
}
package_gnome-desktop-sharp() {
pkgdesc="GNOME desktop bindings for C#"
depends=('libgnome-desktop-sharp' 'gtksourceview2-sharp' 'rsvg2-sharp' 'vte-sharp' 'wnck-sharp')
replaces=('gtkhtml-sharp')
}
package_libgnome-desktop-sharp() {
pkgdesc="Mono bindings for libgnome-desktop"
depends=('gtk-sharp-2' 'gnome-desktop2')
cd $pkgbase-$pkgver
make -C gnomedesktop install DESTDIR="$pkgdir"
}
package_gtksourceview2-sharp() {
pkgdesc="Mono bindings for gtksourceview2"
depends=('gtk-sharp-2' 'gtksourceview2')
cd $pkgbase-$pkgver
make -C gtksourceview install DESTDIR="$pkgdir"
}
package_rsvg2-sharp() {
pkgdesc="Mono bindings for librsvg"
depends=('gtk-sharp-2' 'librsvg')
cd $pkgbase-$pkgver
make -C rsvg install DESTDIR="$pkgdir"
}
package_vte-sharp() {
pkgdesc="Mono bindings for libvte"
depends=('gtk-sharp-2' 'vte')
cd $pkgbase-$pkgver
make -C vte install DESTDIR="$pkgdir"
}
package_wnck-sharp() {
pkgdesc="Mono bindings for libwnck"
depends=('gtk-sharp-2' 'libwnck')
cd $pkgbase-$pkgver
make -C wnck install DESTDIR="$pkgdir"
}
|
