blob: c934ebab371bfa0ed434cb48355acdaf27611305 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# $Id: PKGBUILD 206120 2014-02-19 05:02:54Z pierre $
# Maintainer: Pierre Schmitz <pierre@archlinux.de>
# Contributor: Douglas Soares de Andrade <douglas@archlinux.org>
# Contributor: Tom Newsom <Jeepster@gmx.co.uk>
pkgname=lynx
pkgver=2.8.8
_relver=${pkgver}rel.1
pkgrel=1
pkgdesc="A text browser for the World Wide Web"
url="http://lynx.isc.org/"
arch=('i686' 'x86_64')
license=('GPL')
depends=('openssl')
backup=('etc/lynx.cfg')
source=("http://lynx.isc.org/current/${pkgname}${_relver}.tar.bz2"
"http://lynx.isc.org/current/${pkgname}${_relver}.tar.bz2.asc")
md5sums=('f467c043fe9a3963fc1c05f54923803f'
'SKIP')
build() {
cd ${srcdir}/${pkgname}${pkgver//./-}
./configure --prefix=/usr \
--sysconfdir=/etc \
--with-ssl=/usr \
--enable-nls \
--enable-ipv6 \
--mandir=/usr/share/man
make
}
package() {
cd ${srcdir}/${pkgname}${pkgver//./-}
make DESTDIR=${pkgdir} install
# FS#20404 - points to local help
sed -i -e "s|^HELPFILE.*$|HELPFILE:file:///usr/share/doc/lynx/lynx_help/lynx_help_main.html|" ${pkgdir}/etc/lynx.cfg
install -d ${pkgdir}/usr/share/doc/lynx
cp -rf lynx_help ${pkgdir}/usr/share/doc/lynx
}
|
