blob: aa1025087ccd25803106443451d040b20a064b84 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# $Id: PKGBUILD 216569 2014-07-06 14:57:20Z fyan $
# Maintainer: Felix Yan <felixonmars@gmail.com>
# Contributor: lilydjwg <lilydjwg@gmail.com>
_name=cffi
pkgbase=python-$_name
pkgname=(python-$_name python2-$_name)
pkgver=0.8.6
pkgrel=1
pkgdesc="Foreign Function Interface for Python calling C code"
arch=('i686' 'x86_64')
url="http://cffi.readthedocs.org/"
license=('MIT')
makedepends=('python-setuptools' 'python2-setuptools' 'python-pycparser' 'python2-pycparser')
checkdepends=('python-pytest' 'python2-pytest')
source=("http://pypi.python.org/packages/source/c/${_name}/${_name}-${pkgver}.tar.gz")
sha512sums=('b913d459bf0d355f0cb42fa0587a940c227d6765450033b14ab4d5281173cd1875cd6872911bb4f0b567cc1c5b0ca330615ec5f6ba205b25c41b683ae8c77790')
prepare() {
cp -a $_name-$pkgver{,-py2}
}
build() {
cd "$srcdir/$_name-$pkgver"
python3 setup.py build
cd "$srcdir/$_name-$pkgver-py2"
python2 setup.py build
}
check() {
cd "$srcdir/$_name-$pkgver"
PYTHONPATH="$(pwd)/build/lib.linux-$CARCH-3.4:$PYTHONPATH" py.test
cd "$srcdir/$_name-$pkgver-py2"
PYTHONPATH="$(pwd)/build/lib.linux-$CARCH-2.7:$PYTHONPATH" py.test2
}
package_python-cffi() {
depends=('python' 'python-pycparser')
cd "$srcdir/$_name-$pkgver"
python3 setup.py install --root="$pkgdir/" --optimize=1
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
package_python2-cffi() {
depends=('python2' 'python2-pycparser')
cd "$srcdir/$_name-$pkgver-py2"
python2 setup.py install --root="$pkgdir/" --optimize=1
install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|
