blob: 0d672d6c8d7744e34bd828f95740ef201123d9ff (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# $Id: PKGBUILD 213564 2014-05-24 21:28:05Z eric $
# Maintainer: Eric Bélanger <eric@archlinux.org>
pkgname=wxpython
pkgver=3.0.0.0
_editraver=0.7.20
pkgrel=2
pkgdesc="A wxWidgets GUI toolkit for Python"
arch=('i686' 'x86_64')
license=('custom:wxWindows')
url="http://www.wxpython.org"
depends=('wxgtk' 'python2')
makedepends=('mesa' 'glu')
source=(http://downloads.sourceforge.net/wxpython/wxPython-src-${pkgver}.tar.bz2
http://editra.googlecode.com/files/Editra-${_editraver}.tar.gz)
sha1sums=('48451763275cfe4e5bbec49ccd75bc9652cba719'
'f439f4aa2cb90b8348cebb1670df9cf47ba341ab')
prepare() {
cd "${srcdir}"
find . -type f -exec sed -i 's/env python/env python2/' {} \;
sed -i 's/sys.exit(1)//' Editra-${_editraver}/setup.py
}
build() {
cd "${srcdir}/wxPython-src-${pkgver}"
./configure --prefix=/usr --libdir=/usr/lib --with-gtk=2 --with-opengl --enable-unicode \
--enable-graphics_ctx --enable-mediactrl --disable-precomp-headers \
--with-regex=sys --with-libpng=sys --with-libxpm=sys --with-libjpeg=sys --with-libtiff=sys
cd wxPython
python2 setup.py WXPORT=gtk2 UNICODE=1 build
}
package() {
cd "${srcdir}/wxPython-src-${pkgver}/wxPython"
python2 setup.py WXPORT=gtk2 UNICODE=1 install --root="${pkgdir}"
install -D -m644 ../docs/licence.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
cd "${srcdir}/Editra-${_editraver}"
python2 setup.py install --root="${pkgdir}"
rm -r "${pkgdir}/usr/lib/python2.7/site-packages/wx-3.0-gtk2/wx/tools/Editra"
}
|
